home *** CD-ROM | disk | FTP | other *** search
/ BBS in a Box 7 / BBS in a Box - Macintosh - Volume VII (BBS in a Box) (January 1993).iso / Files / Bus / A / Acius08⁄92.cpt / Acius08_92 / Encoding_Decipheringƒ / Sources / DecryptPicture.a next >
Text File  |  1992-08-17  |  3KB  |  109 lines
  1. ;
  2. ; Deciphering pictures external routine for 4D
  3. ; written by François Marchal, © ACI 1992
  4. ; 
  5. ; Parameters :
  6. ; -> Picture to encode
  7. ; -> Longint key word (you need the same key to encode and to decipher the picture)
  8. ;
  9.  
  10.     CASE    OBJ
  11.     INCLUDE 'traps.a'
  12.     
  13. picsize            EQU        104
  14. signature        EQU        98    
  15. masignature        EQU        $464D
  16. Cle                EQU        100
  17. picend            EQU        6
  18.  
  19.     EXPORT        DecryptPicture
  20.  
  21. DecryptPicture        PROC         
  22.     CODE
  23.  
  24.     LINK        A6,#$0
  25.     MOVEM.L        D4-D7/A4,-(A7)            ; save the used registers
  26.     MOVEA.L        12(A6),A4
  27.     MOVE.L        (A4),A4                    ; A4 : Handle on the picture to encode
  28.     BEQ            Fini                    ; if the Handle passed is Nil, don't do anything
  29.  
  30.     MOVE.L        (A4),A0    
  31.     MOVE.W        signature(A0),D0
  32.     CMPI.W        #masignature,D0            ; verify if the handle hasn't been signed
  33.     BNE.S        fini                    ; if the picture has already been encoded, don't do anything
  34.     
  35.     MOVE.L        8(A6),A0                ; dereferencing (parameter passed in var)
  36.     MOVE.L        (A0),D4                    ; of the deciphering key
  37.     MOVE.L        (A4),A0                    ; dereferencing the Handle
  38.     CMP.L        Cle(A0),D4                ; compare the deciphering key passed with the encoding key
  39.     BNE.S        fini                    ; don't do anything if the keys are not identical
  40.  
  41.     MOVE.L        A4,A0
  42.     _GetHandleSize
  43.     MOVE.L        D0,D7                    ; memorize the size of the new Handle in D7
  44.     BEQ.S        fini                    ; if the Handle is empty, stop
  45.  
  46.     SUB.L        #picsize+picend,D7        ; D7 = size of the handle minus the header minus the picend
  47.     BLE.S        fini                    ; if it's negative, stop
  48.  
  49.     MOVE.L        (A4),A0                    ; go to the beginning of the data
  50.     ADDA.L        #picsize,A0                ; plus the header
  51.  
  52.     MOVE.L        D7,D0                    ; D0 : number of bytes to decipher
  53.  
  54.     MOVE.L        D0,D6
  55.     ANDI.L        #$1F,D6                    ; D6 -> the remainder of the whole division of D7 by 32
  56.  
  57.     LSR.L        #5,D0                    ; divide by 32 of the size of the Handle
  58.     BEQ.S        GereReste                ; allows us to know the number of passes in the loop
  59.  
  60.     SUBQ        #1,D0                    ; take 1 to D7 for the dbra
  61.  
  62. Loop:
  63.     MOVE.L        D4,D5
  64.     SUB.L        D0,D5
  65.     EOR.L        D5,(A0)+                ; 1
  66.     EOR.L        D5,(A0)+                ; 2
  67.     EOR.L        D5,(A0)+                ; 3
  68.     EOR.L        D5,(A0)+                ; 4
  69.     EOR.L        D5,(A0)+                ; 5
  70.     EOR.L        D5,(A0)+                ; 6
  71.     EOR.L        D5,(A0)+                ; 7
  72.     EOR.L        D5,(A0)+                ; 8 x 4 = 32 bytes processed by the loop
  73.     DBRA        D0,Loop                    
  74.  
  75. GereReste:                                ; take care of the remaining bytes
  76.     CMPI.L        #0,D6
  77.     BLE.S        Suite
  78.     EOR.B        D6,(A0)+
  79.     SUBQ        #1,D6
  80.     BRA.S        GereReste
  81.  
  82. Suite:
  83.     MOVEA.L        (A4),A1                    ; A0 = Source -> Block address + block size - header size
  84.     MOVEA.L        A1,A0                    ; A1 = Dest   -> Block address
  85.     ADDA.L        D7,A0                    ; of the data moved toward the bottom of the size of the lock picture
  86.     MOVE.L        #picsize,D0                ; Length -> la taille primary of the Handle
  87.     _BlockMove                            ; replace the primary header on top of mine
  88.  
  89.     MOVE.L        (A4),A0
  90.     ADDA.L        D7,A0                    ; move the 6 bytes from the picend 
  91.     MOVEA.L        A0,A1                    ; to the end of the block
  92.     ADDA.L        #picsize,A1
  93.     MOVE.L        (A1)+,(A0)+
  94.     MOVE.W        (A1)+,(A0)    
  95.  
  96.     MOVE.L        A4,A0                    ; Handle in A0
  97.     MOVE.L        D7,D0                    ; new size in D0    
  98.     ADDQ        #picend,D0
  99.     _SetHandleSize                        ; readjust the size of the Handle (delet the header)
  100.     
  101. Fini:    
  102.     MOVEM.L        (A7)+,D4-D7/A4            ; restoring the registers
  103.     UNLK        A6
  104.     MOVEA.L        (A7)+,A0                ; read the return address
  105.     ADDQ.L        #$8,A7                    ; take the parameters off of the stack
  106.     JMP            (A0)                    ; and return to the calling point
  107.  
  108.     ENDP    
  109.     END